Excel VBA シート名をプログラムで自動的に変更する方法

Excel VBAで「シート名変更」で、シートの名前をプログラムで動的に変更できます。手動で変更するのではなく、VBAコードを使って名前を変更することで、自動化が可能です。具体的な使い方や、注意点やサンプルコードを紹介します。

━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━

命令の意味は分かるけど、何に使うのか分からないと感じている方へ。
30万人が読んだ記事をもとに再構成。

データ分割を題材に、実務の流れの中で理解できる講座です。

↓↓↓↓↓
▶ 自分で作れるレベルへ（こちらから閲覧できます）
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━

Excel VBA シート名変更の利用

Excel VBA シート名変更｜使い方とポイント

Excel VBA シート名変更のサンプルコード

以下コードを標準モジュールに貼り付けて実行してください。

1. Sub シート名一括置換()
3.     Dim fd As FileDialog
4.     Dim filePath As String
5.     Dim wb As Workbook
6.     Dim ws As Worksheet
7.     Dim searchStr As String
8.     Dim replaceStr As String
9.     Dim i As Long
10.     Dim sheetName As String
11.     Dim newName As String
12.     Dim replaceCount As Long
13.     Dim sheetNamesDict As Object
14.     Dim isValid As Boolean
15.     
16.     ' ファイル選択
17.     Set fd = Application.FileDialog(msoFileDialogFilePicker)
18.     With fd
19.         .Title = "Excelファイルを選択してください"
20.         .Filters.Add "Excel Files", "*.xls; *.xlsx; *.xlsm", 1
21.         If .Show <> -1 Then Exit Sub
22.         filePath = .SelectedItems(1)
23.     End With
25.     ' 入力受付（検索文字列）
26.     searchStr = InputBox("シート名の検索文字列を入力してください", "検索文字列")
27.     If searchStr = "" Then Exit Sub
29.     ' 入力受付（置換文字列）＋バリデーション付き再入力ループ
30.     Do
31.         replaceStr = InputBox("シート名の置換文字列を入力してください", "置換文字列")
32.         
33.         If replaceStr = "" Then Exit Sub
34.         
35.         If ContainsInvalidChars(replaceStr) Then
36.             MsgBox "置換シート名に特殊文字（ / \ ? * [ ] ）は使用できません。", vbExclamation
37.             isValid = False
38.         Else
39.             isValid = True
40.         End If
41.     Loop Until isValid
43.     ' ワークブックを開く
44.     Set wb = Workbooks.Open(filePath)
45.     
46.     Set sheetNamesDict = CreateObject("Scripting.Dictionary")
47.     replaceCount = 0
49.     ' 一括処理
50.     For Each ws In wb.Sheets
51.         sheetName = ws.Name
52.         If InStr(sheetName, searchStr) > 0 Then
53.             newName = Replace(sheetName, searchStr, replaceStr)
54.             
55.             ' 長さ制限チェック
56.             If Len(newName) > 31 Then
57.                 MsgBox "シート名が31文字を超えています：" & vbCrLf & newName, vbCritical
58.                 wb.Close SaveChanges:=False
59.                 Exit Sub
60.             End If
61.             
62.             ' 重複チェック
63.             If sheetNamesDict.exists(newName) Then
64.                 MsgBox "シート名が重複します：" & vbCrLf & newName, vbCritical
65.                 wb.Close SaveChanges:=False
66.                 Exit Sub
67.             End If
68.             
69.             sheetNamesDict.Add newName, True
70.             ws.Name = newName
71.             replaceCount = replaceCount + 1
72.         Else
73.             sheetNamesDict(ws.Name) = True
74.         End If
75.     Next
77.     MsgBox replaceCount & " 件のシート名を置換しました。", vbInformation
79.     wb.Save
80.     wb.Close
81. End Sub
83. ' 特殊文字チェック関数
84. Function ContainsInvalidChars(str As String) As Boolean
85.     Dim invalidChars As Variant
86.     Dim ch As Variant
87.     invalidChars = Array("/", "\", "?", "*", "[", "]")
88.     For Each ch In invalidChars
89.         If InStr(str, ch) > 0 Then
90.             ContainsInvalidChars = True
91.             Exit Function
92.         End If
93.     Next
94.     ContainsInvalidChars = False
95. End Function