Excel VBA シートを新規ブックにコピーして名前を付けて保存する実践例

Excel VBAでシートコピー（新規ブックにコピーし、名前を付けて保存）は、既存のシートを新しいブックにコピーして、その新しいブックに名前を付けて保存する操作を指します。この操作を行えば、特定のシートだけを別のファイルとして保存できます。具体的な使い方や、注意点やサンプルコードを紹介します。

なお、インターネット上で紹介されている古いVBAコードの中には、ActiveWorkbook や Select に依存した書き方が多く、実務では意図しないブックやシートを操作してしまうケースがあります。

本記事では、そうした点にも注意しながら、現在でも使いやすい書き方を中心に解説します。

Excel VBAでシートを新しいブックにコピーするシーンとメリット

特定のシートを新しいブックにコピーする操作は、データ管理や分割作業で非常に便利です。

Excel VBAでシートを新しいブックにコピーする｜使い方

Excel VBA シートコピーのサンプルコード

Workbooks.Addメソッドで新しいブックを作成

Option Explicit

Sub CopyMultipleSheets()
    Dim newBook As Workbook
    Set newBook = Workbooks.Add
End Sub

コピー元のシートを指定して、新しいブックに移します。

Option Explicit

Sub CopyMultipleSheets()
    Dim newBook As Workbook
    Set newBook = Workbooks.Add
    Dim sheetToCopy As Worksheet
    Set sheetToCopy = ThisWorkbook.Sheets("Sheet1")
    
    sheetToCopy.Copy Before:=newBook.Sheets(1)
End Sub

━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
命令は分かる。でも作れない。その差は「作り方」です。
実務では、ここを知った瞬間にマクロが組み立てられるようになります。

▶ 実務マクロ設計ミニガイド（無料）
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━

新しいブックを保存して作業を終了します。

Option Explicit

Sub CopyMultipleSheets()
    Dim newBook As Workbook
    Set newBook = Workbooks.Add
    Dim sheetToCopy As Worksheet
    Set sheetToCopy = ThisWorkbook.Sheets("Sheet1")
    
    sheetToCopy.Copy Before:=newBook.Sheets(1)
    newBook.SaveAs "C:\Users\User\Desktop\Test\新しいファイル.xlsx"
    newBook.Close
End Sub

Dim filePath As String
filePath = "C:\Users\User\Desktop\Test\NewFile_" & Format(Now, "yyyymmdd_hhnnss") & ".xlsx"
newBook.SaveAs filePath

数式・書式を含めず、値だけを新規ブックにコピーする。

シートを新規ブックにコピーすると、数式、書式、条件付き書式まで一緒にコピーされます。提出用・共有用ファイルでは、「値だけにしたい」というケースも多いため、その場合は 値貼り付け（PasteSpecial） を使います。

Option Explicit

Sub CopySheetValuesOnly()
    Dim wsSource As Worksheet
    Dim wsTarget As Worksheet
    Dim newBook As Workbook
    
    Set wsSource = ThisWorkbook.Worksheets("Sheet1")
    
    ' 新規ブックを作成
    Set newBook = Workbooks.Add
    Set wsTarget = newBook.Sheets(1)
    
    ' 値のみコピー
    wsSource.UsedRange.Copy
    wsTarget.Range("A1").PasteSpecial Paste:=xlPasteValues
    
    Application.CutCopyMode = False
End Sub

値のみをコピーすることで、数式エラーや不要な書式崩れを防ぎ、軽量で扱いやすいファイルを作成できます。

SaveAs 処理と組み合わせる場合は、以下コードを追加します。

newBook.SaveAs "C:\Users\User\Desktop\Test\値のみコピー.xlsx"
newBook.Close

複数シートをまとめてコピー

Option Explicit

Sub CopyMultipleSheets()
    Dim newBook As Workbook
    Dim sheetArray As Variant

    ' コピーするシートの名前を配列で指定
    sheetArray = Array("Sheet1", "Sheet2", "Sheet3")

    ' 新しいブックを作成
    Set newBook = Workbooks.Add

    ' シートをコピー
    ThisWorkbook.Sheets(sheetArray).Copy Before:=newBook.Sheets(1)

    ' 新しいブックを保存
    newBook.SaveAs "C:\Users\User\Desktop\Test\新しいファイル.xlsx"
    newBook.Close
End Sub

━━━━━━━━━━━━━━━━━━━━━━━━━━━━
すでに気づいている人もいるかもしれません。
VBAができる人は、特別なコードを書いているわけではなく、
作る順番が違うだけです。まとめたガイドを公開しています。
▶ 実務マクロ設計ミニガイド（無料）
━━━━━━━━━━━━━━━━━━━━━━━━━━━━

新規ブックにコピー、名前を付けて保存

Option Explicit

Sub CopySheetToNewBookAndSave()
    Dim wsSource As Worksheet
    Dim newBook As Workbook
    Dim filePath As String
    
    ' コピー元のシートを指定
    Set wsSource = ThisWorkbook.Sheets("Sheet1")
    
    ' シートを新しいブックにコピー
    wsSource.Copy
    
    ' コピーされたシートがアクティブな新しいブックになる
    Set newBook = ActiveWorkbook
    
    ' 保存先のパスを指定
    filePath = "C:\Users\User\Desktop\NewWorkbook.xlsx"
    
    ' 新しいブックを保存
    newBook.SaveAs filePath
    
    ' 新しいブックを閉じる
    newBook.Close
    
    ' 完了メッセージ
    MsgBox "シートが新規ブックにコピーされ、保存されました！"
End Sub